深度图
。
实际上这个深度值并不是均匀分布的
深度缓冲ZBuffer包含了一系列介于 0.0 和 1.0 之间的深度值，通常用于做深度测试(depth test)，判断遮挡关系的关键数据，虽然我们看不见它，但是它一直存在于显存中，并每帧更新，在URP前向渲染中，一般(当然还有二班的情况，先不展开)是实体渲染完，会有一个CopyDepth的动作（延迟渲染在G-Buffer中自然包含深度信息），这里就是把ZBuffer的数据Copy到一张叫做_CameraDepthTexture的渲染纹理上，供Shader访问，所以这之后，在Shader中就可以通过_CameraDepthTexture访问深度图了，所以我们可以把它的信息提取出来，显示在屏幕上，以便有个更直观的认识。好了，开整:
确保有深度图
选择当前配置，勾选深度图选项:
首先确定当前平台，默认质量等级，该等级下用的哪个配置，然后勾选该配置的深度图选项:
同时保证相机里面的深度图设置采用了URP管线设置。
准备工作
创建RawImage用以显示深度图，确保控件占全屏并且随分辨率大小自动适配
创建材质，Shader，并关联到RawImage，Shader代码如下:
Shader "Unlit/ShowDepthShader"
{
Properties
{
_MainTex ("Texture", 2D) = "white" {}
}
SubShader
{
//URP下实体渲染完毕才会写入深度图，所以想访问它就要在Transparent里面访问
Tags { "RenderType"="Transparent" "Queue" = "Transparent" "RenderPipeline" = "UniversalPipeline"}
LOD 100
Pass
{
HLSLPROGRAM
#pragma vertex vert
#pragma fragment frag
#include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"
TEXTURE2D(_CameraDepthTexture);
SAMPLER(sampler_CameraDepthTexture);
struct appdata
{
float4 vertex : POSITION;
};
struct v2f
{
float4 vertex : SV_POSITION;
float4 screenPos : TEXCOORD0;
};
v2f vert(appdata v)
{
v2f o;
o.vertex = TransformObjectToHClip(v.vertex); //到裁切空间
o.screenPos = ComputeScreenPos(o.vertex); //屏幕空间的齐次坐标
return o;
}
half4 frag(v2f v) : SV_Target
{
float2 screenPos = v.screenPos.xy / v.screenPos.w; //计算屏幕空间的UV(去齐次)
float depth = SAMPLE_TEXTURE2D(_CameraDepthTexture, sampler_CameraDepthTexture, screenPos).r; //采样深度
float depthValue = Linear01Depth(depth, _ZBufferParams); //转换深度到0-1区间灰度值
return float4(depthValue, depthValue, depthValue, 1.0); //返回显示灰度颜色
}
ENDHLSL
}
}
}
这里面要注意的是，URP下实体渲染完毕才会写入深度图，所以想访问它就要在Transparent渲染队列中，所以注意Shader的Tags.
另外VertexShader中计算的屏幕坐标是齐次坐标，要换成真正的屏幕UV坐标，要去齐次。
深度值一般(一样有二班)写在深度贴图的r通道，所以我们采样出来后只取其r就好了。
因为在透视投影中，深度值并不是线性的，所以要转换成线性灰度图，就要做一个线性转换，Unity为我们提供好了转换函数: Linear01Depth
运行项目:
上图就是以灰度显示的深度图信息，越黑的地方离摄像机越近，越亮的地方离摄像机越远。
今天就到这里吧。最后给出项目源码地址：显示深度图信息
【转载请注明出处】
