先码上效果图：

Sample Toon.png

1、基本思想

1. 通过物体法线与灯光方向的点积来获得基础的漫反射效果
2. 通过floor函数 来将漫反射灯光颜色进行离散切割，获得卡通的硬过渡效果
3. 最后将灯光与贴图颜色相乘获得最后的效果

2、代码展示

Shader "Roystan/Toon/Lit"
{
    Properties
    {
        _Color("Color", Color) = (1,1,1,1)
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags 
        { 
            "RenderType" = "Opaque"
            "LightMode" = "ForwardBase"
        }

        UsePass "Legacy Shaders/VertexLit/SHADOWCASTER" //引入Unity的Pass通道，此通道用来渲染物体的阴影

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "UnityCG.cginc"
           #include "Lighting.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float3 normal : NORMAL;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float3 worldNormal : NORMAL;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                return o;
            }

            float4 _Color;

            float4 frag (v2f i) : SV_Target
            {
                float NdotL = dot(i.worldNormal, _WorldSpaceLightPos0);
                //此时场景中的光为平行光，所以_WorldSpaceLightPos0中存储的是光的方向矢量（Vector 3）
                float light = saturate(floor(NdotL * 3 ) / (2 - 0.5)) * _LightColor0;//经验模型，控制颜色的突变，通过floor函数

                float4 col = tex2D(_MainTex, i.uv);
                return (col * _Color) * (light + unity_AmbientSky);//在灯光中引入环境光的颜色
            }
            ENDCG
        }
    }
}

3、总结

本次Shader的关键是片元着色器中的light这行代码，通过对NdotL（返回世界空间法线与光源方向的点积）乘以3，将范围扩充到[-3,3]，然后通过floor函数得到固定的数字（-3，-2，-1，0，1，2，3）。如果此时对其进行saturate只能获得0和1的二态光照效果，所以需要进行缩放来获得更多更合适的阴影效果。当然，随着分子的增大，颜色会偏向0，也就是说会变暗，同时对比度下降