在搞明白这三者的区别之前，我们来看一看下面的代码
FYPerson *p1 = [FYPerson alloc];
FYPerson *p2 = [p1 init];
FYPerson *p3 = [p1 init];
FYNSLog(@"%@ - %p - %p",p1,p1,&p1);
FYNSLog(@"%@ - %p - %p",p2,p2,&p2);
FYNSLog(@"%@ - %p - %p",p3,p3,&p3);
分别输出3个对象的内容、对象指针指向的内存地址、对象的指针地址，下面是打印结果：
<FYPerson: 0x281adfe90> - 0x281adfe90 - 0x16f1b5c28
<FYPerson: 0x281adfe90> - 0x281adfe90 - 0x16f1b5c20
<FYPerson: 0x281adfe90> - 0x281adfe90 - 0x16f1b5c18
通过上面的打印结果，你可能会看出一些端倪：
三个对象指向的是同一块内存空间，所以内容和内存地址是相同的，但是指针地址是不同的
接下来，我们来探索alloc、init到底做了什么
准备工作
- 作为一个NB的程序员，一定要经常去看底层源码，这里我就以当前最新的objc4-781源码为例来探索
- 编译源码可参考iOS-底层（3）：objc4-781 源码编译及调试
alloc 源码探索
alloc init流程图
- 【第一步】首先根据main函数中的LGPerson类的alloc方法进入alloc方法的源码实现（即源码分析开始），
//alloc源码分析-第一步
+ (id)alloc {
return _objc_rootAlloc(self);
}
- 【第二步】跳转至_objc_rootAlloc的源码实现
id
_objc_rootAlloc(Class cls)
{
return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}
- 【第三步】跳转至callAlloc的源码实现
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)// alloc 源码 第三步
{
#if __OBJC2__ //有可用的编译器优化
/*
参考链接：https://www.jianshu.com/p/536824702ab6
*/
// checkNil 为false，!cls 也为false ，所以slowpath 为 false，假值判断不会走到if里面，即不会返回nil
if (slowpath(checkNil && !cls)) return nil;
//判断一个类是否有自定义的 +allocWithZone 实现，没有则走到if里面的实现
if (fastpath(!cls->ISA()->hasCustomAWZ())) {
return _objc_rootAllocWithZone(cls, nil);
}
#endif
// No shortcuts available. // 没有可用的编译器优化
if (allocWithZone) {
return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
}
return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}
如上所示，在calloc方法中，当我们无法确定实现走到哪步时，可以通过断点调试，判断执行走哪部分逻辑。这里是执行到_objc_rootAllocWithZone
slowpath & fastpath
其中关于slowpath和fastpath这里需要简要说明下，这两个都是objc源码中定义的宏，其定义如下
//x很可能为真， fastpath 可以简称为 真值判断
#define fastpath(x) (__builtin_expect(bool(x), 1))
//x很可能为假，slowpath 可以简称为 假值判断
#define slowpath(x) (__builtin_expect(bool(x), 0))
其中的__builtin_expect指令是由gcc引入的
1、目的：编译器可以对代码进行优化，以减少指令跳转带来的性能下降。即性能优化
2、作用：允许程序员将最有可能执行的分支告诉编译器。
3、指令的写法为：__builtin_expect(EXP, N)。表示 EXP==N的概率很大。
4、fastpath定义中__builtin_expect((x),1)表示 x 的值为真的可能性更大；即 执行if 里面语句的机会更大
5、slowpath定义中的__builtin_expect((x),0)表示x 的值为假的可能性更大。即执行 else 里面语句的机会更大
6、在日常的开发中，也可以通过设置来优化编译器，达到性能优化的目的，设置的路径为：Build Setting --> Optimization Level --> Debug -->将None改为fastest或者 smallest
cls->ISA()->hasCustomAWZ()
其中fastpath中的cls->ISA()->hasCustomAWZ()表示判断一个类是否有自定义的 +allocWithZone 实现，这里通过断点调试，是没有自定义的实现，所以会执行到 if 里面的代码，即走到_objc_rootAllocWithZone
id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)
{
// allocWithZone under __OBJC2__ ignores the zone parameter
return _class_createInstanceFromZone(cls, 0, nil,
OBJECT_CONSTRUCT_CALL_BADALLOC);
}
- 【第四步】跳转至
_objc_rootAllocWithZone的源码实现
id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)// alloc 源码 第四步
{
// allocWithZone under __OBJC2__ ignores the zone parameter
//zone 参数不再使用 类创建实例内存空间
return _class_createInstanceFromZone(cls, 0, nil,
OBJECT_CONSTRUCT_CALL_BADALLOC);
}
- 【第五步】跳转至_class_createInstanceFromZone的源码实现，这部分是alloc源码的核心操作，由下面的流程图及源码可知，该方法的实现主要分为三部分
- cls->instanceSize：计算需要开辟的内存空间大小
- calloc：申请内存，返回地址指针
- obj->initInstanceIsa：将 类 与 isa 关联
static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
int construct_flags = OBJECT_CONSTRUCT_NONE,
bool cxxConstruct = true,
size_t *outAllocatedSize = nil)// alloc 源码 第五步
{
ASSERT(cls->isRealized()); //检查是否已经实现
// Read class's info bits all at once for performance
//一次性读取类的位信息以提高性能
bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
bool hasCxxDtor = cls->hasCxxDtor();
bool fast = cls->canAllocNonpointer();
size_t size;
//计算需要开辟的内存大小，传入的extraBytes 为 0
size = cls->instanceSize(extraBytes);
if (outAllocatedSize) *outAllocatedSize = size;
id obj;
if (zone) {
obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
} else {
//申请内存
obj = (id)calloc(1, size);
}
if (slowpath(!obj)) {
if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
return _objc_callBadAllocHandler(cls);
}
return nil;
}
if (!zone && fast) {
//将 cls类 与 obj指针（即isa） 关联
obj->initInstanceIsa(cls, hasCxxDtor);
} else {
// Use raw pointer isa on the assumption that they might be
// doing something weird with the zone or RR.
obj->initIsa(cls);
}
if (fastpath(!hasCxxCtor)) {
return obj;
}
construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
return object_cxxConstructFromClass(obj, cls, construct_flags);
}
我们看一下cls->instanceSize是如何计算的
1、instanceSize的源码实现
size_t instanceSize(size_t extraBytes) const {
//编译器快速计算内存大小
if (fastpath(cache.hasFastInstanceSize(extraBytes))) {
return cache.fastInstanceSize(extraBytes);
}
// 计算类中所有属性的大小 + 额外的字节数0
size_t size = alignedInstanceSize() + extraBytes;
// CF requires all objects be at least 16 bytes.
//如果size 小于 16，最小取16
if (size < 16) size = 16;
return size;
}
2、跳转至fastInstanceSize的源码实现，通过断点调试，会执行到align16
size_t fastInstanceSize(size_t extra) const
{
ASSERT(hasFastInstanceSize(extra));
//Gcc的内建函数 __builtin_constant_p 用于判断一个值是否为编译时常数，如果参数EXP 的值是常数，函数返回 1，否则返回 0
if (__builtin_constant_p(extra) && extra == 0) {
return _flags & FAST_CACHE_ALLOC_MASK16;
} else {
size_t size = _flags & FAST_CACHE_ALLOC_MASK;
// remove the FAST_CACHE_ALLOC_DELTA16 that was added
// by setFastInstanceSize
//删除由setFastInstanceSize添加的FAST_CACHE_ALLOC_DELTA16 8个字节
return align16(size + extra - FAST_CACHE_ALLOC_DELTA16);
}
}
3、align16的源码实现，这个方法是16字节对齐算法
//16字节对齐算法，也就是16的倍数
static inline size_t align16(size_t x) {
return (x + size_t(15)) & ~size_t(15);
}
内存字节对齐原则
数据成员对齐规则：struct 或者 union 的数据成员，第一个数据成员放在offset为0的地方，以后每个数据成员存储的起始位置要从该成员大小或者成员的子成员大小（只要该成员有子成员，比如数据、结构体等）的整数倍开始（例如int在32位机中是4字节，则要从4的整数倍地址开始存储）
数据成员为结构体：如果一个结构里有某些结构体成员，则结构体成员要从其内部最大元素大小的整数倍地址开始存储（例如：struct a里面存有struct b，b里面有char、int、double等元素，则b应该从8的整数倍开始存储）
结构体的整体对齐规则：结构体的总大小，即sizeof的结果，必须是其内部做大成员的整数倍，不足的要补齐
为什么需要16字节对齐
需要字节对齐的原因，有以下几点：
- 通常内存是由一个个字节组成的，cpu在存取数据时，并不是以字节为单位存储，而是以块为单位存取，块的大小为内存存取力度。频繁存取字节未对齐的数据，会极大降低cpu的性能，所以可以通过减少存取次数来降低cpu的开销
- 16字节对齐，是由于在一个对象中，第一个属性isa占8字节，当然一个对象肯定还有其他属性，当无属性时，会预留8字节，即16字节对齐，如果不预留，相当于这个对象的isa和其他对象的isa紧挨着，容易造成访问混乱
- 16字节对齐后，可以加快CPU读取速度，同时使访问更安全，不会产生访问混乱的情况
calloc：申请内存，返回地址指针
通过instanceSize计算的内存大小，向内存中申请 大小 为 size的内存，并赋值给obj，因此 obj是指向内存地址的指针
obj = (id)calloc(1, size);
执行完calloc之后，此时obj为0x000000010112efa0，我们平时打印的指针为<FYPerson: 0x01111111f>这样，因为现在obj地址和传入的cls并没有关联，由此可见calloc只是开辟内存
obj->initInstanceIsa：类与isa关联
执行完obj->initInstanceIsa，我们在po一下obj，发现已经将isa和类关联。具体如何关联请看iOS-底层（5）：isa如何与类关联
总结：
- 通过对alloc源码的分析，可以得知alloc的主要目的就是开辟内存，而且开辟的内存需要使用16字节对齐算法，现在开辟的内存的大小基本上都是16的整数倍
- 开辟内存的核心步骤有3步：计算 -- 申请 -- 关联
init 源码探索
- inti的源码实现有以下两种
类方法 init
+ (id)init {
return (id)self;
}
这里的init是一个构造方法 ，是通过工厂设计（工厂方法模式）,主要是用于给用户提供构造方法入口。这里能使用id强转的原因，主要还是因为 内存字节对齐后，可以使用类型强转为你所需的类型
实例方法 init
- (id)init {
return _objc_rootInit(self);
}
id
_objc_rootInit(id obj)
{
// In practice, it will be hard to rely on this function.
// Many classes do not properly chain -init calls.
return obj;
}
返回的是传入的self本身。
new 源码探索
一般在开发中，初始化除了init，还可以使用new，两者本质上并没有什么区别，以下是objc中new的源码实现，通过源码可以得知，new函数中直接调用了callAlloc函数（即alloc中分析的函数），且调用了init函数，所以可以得出new 其实就等价于 [alloc init]的结论
+ (id)new {
return [callAlloc(self, false/*checkNil*/) init];
}
一般我们开发中不使用new，主要有因为：
在开发中我们经常重写init，而用new无法走到自己的init方法里面
