5.1 结构体定义和初始化
Solidity支持通过构造结构体的形式定义新的类型。创建结构体的方法：
// 结构体定义
struct Car {
string model;
uint year;
address owner;
}
定义状态变量结构体和结构体数组：
// 初始化一个结构体变量
Car public car;
// 初始化一个结构体变量数组
Car[] public cars;
5.2 新增
在内存中初始化结构体变量，并推入到状态变量：
// 初始化+新增
function initStructInMemory() external {
// 在内存中初始化结构体的方法
// 方法一：
Car memory toyota = Car("Toyota",1988,msg.sender);
// 方法二：
Car memory lambo = Car({model:"lambo",year:1990,owner:msg.sender});
// 方法三：
Car memory tesla;
tesla.model = "tesla";
tesla.year = 2020;
tesla.owner = msg.sender;
// 将内存中的结构体变量推入到结构体数组状态变量中（memory -> storage）：
cars.push(toyota);
cars.push(lambo);
// 将内存中的结构体变量推入到结构体状态变量中（memory -> storage）：
car = tesla;
}
5.3 修改
修改结构体状态变量，可以通过创建storage引用或者直接修改两种方式：
// 修改
function setYear(uint _year) external {
// 方法一：创建storage引用
Car storage myCar1 = car;
myCar1.year = _year;
Car storage myCar2 = cars[0];
myCar2.year = _year;
// 方法二：直接修改
cars[1].year = _year;
}
5.4 读取
读取状态变量，可以先读取到内存中（memory），或创建引用（storage），或者直接读取：
// 读取一：storage -> memory -> memory
function readCar1() view external returns (Car memory) {
Car memory mycar = cars[0]; // 10479 gas
return mycar;
}
// 读取二：storage -> storage -> memory
function readCar2() view external returns (Car memory) {
Car storage mycar = cars[0]; // 10457 gas
return mycar;
}
// 读取三：storage -> memory
function readCar3() view external returns (Car memory) {
return cars[0]; // 10443 gas
}
虽然使用普通地址访问view函数不消耗gas，但是当调用者是合约时，还是会有gas。
通过比较发现：
- 读取三：直接读从状态变量中读取并返回，消耗gas最少，为10443 gas，数据从storage读取到memory，执行了一次值拷贝。（值拷贝）
- 读取二：先读取到storage再返回，消耗gas次少，为10457 gas，数据从storage读取到storage，执行了一次引用拷贝；从storage读取到memory，执行了一次值拷贝。（引用拷贝+值拷贝）
- 读取一：先读取到memory再返回，消耗gas最多，为10479 gas，数据从storage读取到memory，执行了一次值拷贝；从memory读取到memory，又执行了一次值拷贝。（值拷贝+值拷贝）
5.5 删除
使用delete方法对结构体进行删除，可以删除结构体中的变量，也可以删除结构体数组中的结构体。删除是将对应值置为默认值。
// 删除结构体
function deleteStruct() external {
// 删除结构体中的变量
delete car.year;
// 删除结构体数组中的结构体
delete cars[0];
}
