布林带我之前写过了一篇如何求解的详细解说，这篇还是写它，不是重复之前的内容，而是之前写的交易公式是我野路子出身自己编写的程序，这次看的是科班（系统自带的）如何写的源代码，我们可以从这好好学习一下。
其实现在我写这些解读代码系列，也是一边学习，一边就顺便写出来的，我自己写的代码，大部分都是有一个理念了，就复制系统写好的，再照理念添加买卖条件，大部分都只注意买卖点的准确性，不能让实盘交易与历史测试有出入的，所以总写出有点缺陷的代码。在这我再次提醒各位朋友，在做程序化的交易时，一定要把买卖点位做好准确，不能有很大的滑点误差，否则实盘将是一个悲剧，这篇文章主要的也就是让各位明白这买卖点位的重要性的。
boll通道突破程序化系统基本操作规则如下：
入场条件:
1、价格突破通道上轨，则开多仓。
2、价格突破通道下轨，则开空仓。
出场条件:
1、价格突破通道上轨，则平空仓。
2、价格突破通道下轨，则平多仓。
好了，废话不说了，我们直接来看代码：
Params
Numeric AvgLen(3); //声明数值型参数AvgLen，其实就是均线周期的参数为3.//
Numeric Disp(16); //声明数值型参数Disp，赋值16.//
Numeric SDLen(12); //声明数值型参数SDLen，赋值12.//
Numeric SDev(2); //声明数值型参数SDev，赋值2.//
Vars
Numeric Price; //声明变量价格Price。//
NumericSeries AvgVal(0); //声明序列变量AvgVal，其实也就是中间带。//
NumericSeries SDmult(0) ; //声明序列变量SDmult，这个计算通道距离。//
NumericSeries DispTop(0); //声明序列变量DispTop，这个通道上轨。//
NumericSeries DispBottom(0); //声明序列变量DispBottom，这个通道下轨。//
Numeric MinPoint; //声明MinPoint，这个是最小变动价位。//
Begin
If(!CallAuctionFilter()) Return;// 集合竞价和小节休息过滤。//
MinPoint = MinMove * PriceScale; //最小变动价位=商品的最小变动量 *商品的计数单位。//
Price = Close;//术语是把收盘价赋值给价格，直白就是价格等于收盘价。//
//下来就是人家计算的布林带。//
AvgVal = Average(Price,AvgLen); //中间带均线计算，3个周期的收盘价移动均线。//
SDmult = StandardDev(Price,SDLen,2)*SDev;//求标准差函数我们说过了，这边就是计算12周期以来收盘价的样本标准差，再乘以系数2。//
DispTop = AvgVal[Disp] + SDmult;//中间带AvgVal[16]，从当前k线往回倒腾第16个值，所以这意思就明白了，上轨=AvfVal[16]+SDmult.//
DispBottom = AvgVal[Disp] - SDmult;//同理的，下轨道就是减去通道距离SDmult//
PlotNumeric("DispTop",DispTop);//画线了，显示上轨//
PlotNumeric("DispBottom",DispBottom);//显示下轨//
//接下来开仓买入场。//
If(MarketPosition == 0)//假如当前为空仓，执行下列操作。//
{
If(High >= DispTop[1])//假如最高价大于等于前一个上轨价，就是突破的意思，执行下列买入操作。//
{
Buy(0,Max(Open,DispTop[1]));//这里的0意思是1手，Max（Open，DisTop[1]）就是两者中哪个值大，就当成开仓价格了。//
}
}
//系统出场//
If(MarketPosition == 1 and BarsSinceEntry > 0)//假如持多仓，并且当前持仓的第一个建仓位置k线大于0，也就是开仓后起码从第二根k线开始。//
{
If(Low <= DispBottom[1])//假如低价小于或等于前一个下轨值，执行卖出操作。//
{
Sell(0,Min(Open,DispBottom[1])); //平仓1手，Min（）同理两者中哪个值小，就用它当成平仓价。//
}
}
//开仓卖出操作。//
If(MarketPosition == 0)//空仓时候。//
{
If(Low <= DispBottom[1])//假如低价小于或等于前一个下轨值，执行卖出操作。//
{
SellShort(0,Min(Open,DispBottom[1]));//开仓卖出1手，Min（）两者中哪个值小，就用它当成平仓价。//
}
}
//平仓操作。//
If(MarketPosition == -1 and BarsSinceEntry > 0)//假如持多仓，并且当前持仓的第一个建仓位置k线大于0，也就是开仓后起码从第二根k线开始。//
{
If(High >= DispTop[1])//假如最高价大于等于前一个上轨价，就是突破的意思，执行下列买入操作。//
{
BuyToCover(0,Max(Open,DispTop[1]));//开仓买入1手，Max（）两者中哪个值大，就用它当成平仓价。//
}
}
End
看着结果还是可以的，就像我开头提醒的，对程序化来说买卖点位是很重要的，看我把买卖点位的代码变下，再对比一下收益图，大家就会发现这差距多大了。变化代码如下：
Params
Numeric AvgLen(3);
Numeric Disp(16);
Numeric SDLen(12);
Numeric SDev(2);
Vars
Numeric Price;
NumericSeries AvgVal(0);
NumericSeries SDmult(0) ;
NumericSeries DispTop(0);
NumericSeries DispBottom(0);
Numeric MinPoint;
Begin
If(!CallAuctionFilter()) Return;
MinPoint = MinMove*PriceScale;
Price = Close;
AvgVal = Average(Price,AvgLen);
SDmult = StandardDev(Price,SDLen,2)*SDev;
DispTop = AvgVal[Disp] + SDmult;
DispBottom = AvgVal[Disp] - SDmult;
PlotNumeric("DispTop",DispTop);
PlotNumeric("DispBottom",DispBottom);
If(MarketPosition == 0)
{
If(Close[1] >= DispTop[1])
{
Buy(0,Open);
}
}
If(MarketPosition == 1 and BarsSinceEntry > 0)
{
If(Close[1] <= DispBottom[1])
{
Sell(0,Open);
}
}
If(MarketPosition == 0)
{
If(Close[1] <= DispBottom[1])
{
SellShort(0,Open);
}
}
If(MarketPosition == -1 and BarsSinceEntry > 0)
{
If(Close[1] >= DispTop[1])
{
BuyToCover(0,Open);
}
}
End
看到了吧，这两个图对比一下，这第二个代码这波动的让人难受吧。再看第三个严重延误的买卖代码，可以说这是个坑爹的代码：
Params
Numeric AvgLen(3);
Numeric Disp(16);
Numeric SDLen(12);
Numeric SDev(2);
Vars
Numeric Price;
NumericSeries AvgVal(0);
NumericSeries SDmult(0) ;
NumericSeries DispTop(0);
NumericSeries DispBottom(0);
Numeric MinPoint;
Begin
If(!CallAuctionFilter()) Return;
MinPoint = MinMove*PriceScale;
Price = Close;
AvgVal = Average(Price,AvgLen);
SDmult = StandardDev(Price,SDLen,2)*SDev;
DispTop = AvgVal[Disp] + SDmult;
DispBottom = AvgVal[Disp] - SDmult;
PlotNumeric("DispTop",DispTop);
PlotNumeric("DispBottom",DispBottom);
If(MarketPosition == 0)
{
If(Close >= DispTop[1])
{
Buy(0,Open);
}
}
If(MarketPosition == 1 and BarsSinceEntry > 0)
{
If(Close <= DispBottom[1])
{
Sell(0,Open);
}
}
If(MarketPosition == 0)
{
If(Close <= DispBottom[1])
{
SellShort(0,Open);
}
}
If(MarketPosition == -1 and BarsSinceEntry > 0)
{
If(Close >= DispTop[1])
{
BuyToCover(0,Open);
}
}
End
看到这收益多让人心动啊，可惜这是错觉，当你实盘观察的时候，就会发现，开仓点位总是在延误，价格明明已经过了，才显示出来，这根本就没法操作的，你说可以挂单啊，但挂单，你有那预见性吗？或者说挂单一定能让价格返回来成交的概率有多少？
所以，最后还是强调一遍，程序化必须明确买卖点位。
