前面文章介绍了EQ-5D量表SDTM的处理（SDTM：EQ-5D量表的Mapping），这篇介绍ADaM的处理。
文章分为2部分，前一部分是，Index Value的获取；后一部分，是SAS编程的注意点。
科研人员应该是比较关心Index Value的获取。后半部分，对纵向数据集的横向处理方法，SAS程序员可以留意一下，建议使用Data步中的Retain语句。
ADaM的处理时基于分析的需要，SAP中应该有对EQ-5D内容的具体描述。常规的做法是，对分类变量进行频数汇总（5个维度问题的具体回答），对数值型变量进行统计描述（VAS Score，Index Value）。
1. Index Value的获取
SDTM中已经获取5个维度的回答结果以及VAS Score，对应的QSTESTCD可以直接作为PARAMCD进行使用。在文章EQ-5D量表简介中，介绍的Index Value是通过表示健康状态的五位数(e.g. 21232)的权重值计算所得。
目前EQ-5D官网已经已不同地区、不同健康状态对应的Index Value查询表了。（来源：Crosswalk Index Value Calculator – EQ-5D (euroqol.org)）
查询表格是一个EXCEL文件，第3个sheet中列举了，不同健康状态、不同地区对应的Index Value。具体项目中，我们只需要将文件导入SAS直接拼接获取。
这里有一个注意点，网站上有一个说明 Crosswalk value sets for the EQ-5D-5L are available for the following countries: Denmark, France, Germany, Japan, the Netherlands, Spain, Thailand, UK, US and Zimbabwe.（EQ-5D-5L Crosswalk value sets适用于以下国家/地区：丹麦、法国、德国、日本、荷兰、西班牙、泰国、英国、美国和津巴布韦）。
按照上面所说，也只能这些地区的人群能够获取到Index Value。不过在一个多中心项目的SAP中，有这样的一句说明：
This table is developed by EuroQOL Group for different countries. The United Kingdom (UK) Measurement and Valuation of Health study value set is generally considered the base case scoring function for the purposes of publication (Dolan, 1997). EQ-5D-5L utility index score will be calculated based on UK values with utility index scores ranging from -0.594 (worst imaginable health state) to 1 (full health). A list of available value sets can be found on the EuroQol website.
基于此，项目中使用的是UK的数据。
2. SAS编程的注意点
EQ-5D量表编程的难点在于，五位数健康状态的生成。只要获取了这五位数，Index Value可以直接通过拼接外部表格进行获取。
我构建了了一个用于说明的临时数据集Tmp：
从数据集看，SCREENING访视5维度的回答是1,1,1,1,2，所以对应的健康状态为11112。这个结果是对纵向数据进行横向拼接，常用的处理方法有两种，第一是，通过Transpose进行转置；第二，通过Data步中的Retain语句进行实现。
2.1 Transpose过程步
第1种方法实现如下：
proc transpose data = tmp out = tmp1;
by usubjid visitnum visit;
var qsstresc;
id paramcd;
run;
data tmp2;
set tmp1;
paramcd = "EQ5D5LHS"; /*Health State*/
if cmiss(of eq5d5l01-eq5d5l05) = 0 then avalc = cats(of eq5d5l01-eq5d5l05);
else avalc = "";
run;
从结果中，可以看到每个访视的健康状况生成完毕。移除不必要的变量后，直接竖向拼接回原数据集。
cats函数这里，变量名连写是需要添加of的，否则会默认当成数值运算式，当然也可以使用逗号,进行间隔：
avalc = cats(eq5d5l01,eq5d5l02,eq5d5l03,eq5d5l04,,eq5d5l05);
2.2 Data步的Retain语句
大多数人第一次接触Retain语句，可能是数值变量的分组求和。不止是数值变量，字符变量也是可以实现“分组求和”的。
第2种方法实现如下：
data tmp1;
set tmp;
length avalc_ $5;
retain avalc_ " ";
if paramcd = "EQ5D5L01" then avalc_ = strip(qsstresc);
else if paramcd in ("EQ5D5L02" "EQ5D5L03" "EQ5D5L04" "EQ5D5L05") then avalc_ = strip(avalc_)||strip(qsstresc);
else avalc_ = "";
output;
if paramcd = "EQ5D5L05" then do;
paramcd = "EQ5D5LHS"; /*Health State*/
if length(avalc_) = 5 then avalc = avalc_;
else avalc = "";
aval = .;
output;
end;
run;
从结果看，Retain语句直接在原有的数据集中新增了一条记录，与Transpose过程步相比简洁了不少。
比较两种实现方法，我推荐使用Data步的Retain语句。除了过程简洁一点之外，还有一点好处是，数据集中的基础变量值是保留下来的。构建的临时数据集变量很少，正常ADaM数据集还有不少其他变量，Transpose过程步只会保留by语句变量，缺少的变量还需要单独添加，比较麻烦。
什么时候建议使用Transpose过程步呢？有一种情况合适，SDTM编程的时，Test结果大多横向放置，这时候保留ID变量(By 语句)，将横向的结果转置为竖向结果。这种操作，比单独对每一个Test做Output输出要方便的多。
总结
这篇文章介绍EQ-5D的Index Value的获取，以及ADaM编程过程中对于Health State的拼接5位数的处理，处理推荐使用Data步中的Retain语句。
感谢阅读！若有疑问，欢迎评论区交流！
相关文章：
EQ-5D量表简介
SDTM：QRS域相关变量(CAT, TEST/CD)的命名规则
SDTM：EQ-5D量表的Mapping
