1. 前向渲染是最常用的一种渲染路径，每次Draw的时候都要对一个物体都要进行进行一次（或者多次）光照计算，然后再对下一个物体进行光照计算。如果在Fragment shader中计算，这种计算量是很大的。
2. 前向渲染在pass中要使用“LightMode”=“ForwardBase”等标签。使用这个标签后unity才能给内置的一些变量正确赋值。如_WorldSpaceLightPos0，_LightColor0等。在ForwardBase的Pass中会计算最重要的平行光、逐顶点/SH光源与LightMaps和环境光。
3. 前向渲染路径还有一种路径为"ForwardAdd"路径，包含此标签的Pass会计算额外的逐像素光源，每个Pass对应一个光源。也就是说如果场景中有m个光源，那么就会执行对应的Pass m次，如果shader中没有给对应的光源编写Pass，则物体不会受这个光源的影响。
4. 一个前向渲染实例：包含一个最重要的平行光，4个点光源。其中环境光，平行光在ForwardBase 的Pass中逐像素计算（frag中）（还可以计算光照贴图等）。4个点光源（V5.6中设置为auto不好使，设置为Important）在ForwardAdd中逐像素计算，每个点光源执行一次ForwardAdd Pass。考虑了光源衰减因子，平行光不衰减，点光源采用unity中内置变量计算衰减，使用衰减纹理计算，避免了过多的距离平方开方计算等。

Shader "FFD/ForwardRenderingBasePass"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            Tags{"LightMode" = "ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase //可以正确得到光源衰减等信息

            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 pos : SV_POSITION;
                float3 worldNormal : NORMAL;
                SHADOW_COORDS(2)
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
            
            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
                o.worldNormal = mul(v.normal,(float3x3)unity_WorldToObject);
                TRANSFER_SHADOW(o);
                return o;
            }
            
            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);

                float3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                float3 worldNormal = normalize(i.worldNormal);

                fixed4 ambient = fixed4(UNITY_LIGHTMODEL_AMBIENT.xyz,1);
                fixed4 diffuse = fixed4(_LightColor0.xyz*saturate(dot(worldNormal,worldLightDir)),1);
                col = col*(ambient+diffuse);
                fixed shadow = SHADOW_ATTENUATION(i);
                col = shadow*col;
                return col;
            }
            ENDCG
        }


        Pass{
            Tags { "LightMode" = "ForwardAdd"}
            Blend One One
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdadd   //可以正确得到光源衰减等信息

            #include "unitycg.cginc"
            #include "lighting.cginc"
            #include "autolight.cginc "

            struct v2f{
                float4 pos : SV_POSITION;
                float3 normalWorld : NORMAL;
                float4 posWorld : TEXCOORD0;
            };

            v2f vert(appdata_base IN)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(IN.vertex);
                o.normalWorld = mul(IN.normal,(float3x3)unity_WorldToObject);
                o.posWorld = mul(IN.vertex,unity_ObjectToWorld);
                return o;
            }
            fixed4 frag (v2f IN) : SV_Target
            {
                fixed atten;
                #ifdef USING_DIRECTIONAL_LIGHT
                    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz);
                    atten = 1;
                #else
                    fixed3 worldLightDir = normalize(_WorldSpaceLightPos0.xyz - IN.posWorld.xyz);
                    float3 lightCoord = mul(unity_WorldToLight,IN.posWorld).xyz;
                    atten = tex2D(_LightTexture0,dot(lightCoord,lightCoord).rr).UNITY_ATTEN_CHANNEL;

                #endif
                fixed3 diffuse = _LightColor0.xyz * atten * saturate(dot(worldLightDir,normalize(IN.normalWorld)));
                return fixed4(diffuse,1);
            }
            ENDCG
        }
    }
    FallBack "Specular"
}