在前面的文章SAS编程：频数汇总时如何处理分析分组种类不全的情况？中，介绍了Means过程步中使用Preloadfmt选项输出分析分组计数为０的记录。
我们在分组计数时，除了要求所有分析分组都输出外，有时还需要使分组类别以固定的顺序输出。后者常发生在分组变量类别无明显的顺序逻辑关系（例如，Race的汇总输出），或分组变量有顺序逻辑关系但默认排序与逻辑顺序不同的情况下（例如，Sex的汇总输出）。
上一篇文章，输出的Sex汇总结果如下，这时候如果要求输出结果以Male、Female的顺序输出，如何处理呢？
与上一篇文章对应，也是两种方法。
Dummy数据集
第一种，在Dummy数据集时，新建一个排序变量对应每一个分组类别的位置，最后输出时按该变量排序。
具体的演示代码如下：
**Get data from sashelp.class;
data class;
set sashelp.class;
where sex = "M";
run;
**Count for each sex category;
proc freq data = class;
tables sex / out = result1(keep = sex count);
run;
**Create a dummy dataset for missing category;
data dummy;
length sex $1;
sex = "F"; ord = 2; output;
sex = "M"; ord = 1; output;
run;
**Merge result dataset with dummy dataset;
data result;
merge dummy result1;
by sex;
if count = . then count = 0;
proc sort;
by ord;
run;
最后输出结果实现了，Male在前、Female在后的排列效果。
Preloadfmt + Notsorted选项
第二种，在使用Preloadfmt选项设置分组变量的Format时，使用notsorted选项固定分组变量的Format的顺序。
关于Format过程步的notsorted选项的介绍，可以参考这篇文章，SAS编程：Proc Format中NOTSORTED选项简介。
示例代码如下：
**Get data from sashelp.class;
data class2;
set sashelp.class;
where sex = "M";
*Create count flag;
flag = 1;
run;
**Set format for class var;
proc format;
value $sex (notsorted)
"M"="Male"
"F"="Female"
;
run;
**Get count;
proc means data = class2 nway completetypes;
class sex/ preloadfmt order = data;
var flag;
output n=count out = result2;
format sex $sex.;
run;
这里有一个注意点，除了使用preloadfmt、notsorted选项外，在Means过程步的Class语句中，还需要使用 order = data 这一个选项，这样才能实现按照Format定义的顺序进行输出。读者可以自行复制代码，进行修改验证。
Means过程步Class语句中的order =选项总共有４种排序方式，具体每一种排序方式的说明可以参考官方文档 SAS Help Center: Syntax: PROC MEANS CLASS Statement。
- DATA
- FORMATTED
- FREQ
- UNFORMATTED
结语
Preloadfmt以及notsorted选项能够解决频数汇总时分组类别计数为０与分组类别排序问题，同时也能够简化代码，推荐读者朋友们在频数汇总中使用这两个选项。
感谢阅读！若有疑问，欢迎评论区交流！
