写在前面：
对Metal技术感兴趣的同学，可以关注我的专题:Metal专辑
也可以关注我个人的简书账号：张芳涛
所有的代码存储的Github地址是：Metal
正文
Computer Graphics一个重要的话题是灯光和阴影效果。本文将讲解Metal阴影效果的一些基本用法。首先，我们设置一个场景：
float differenceOp(float d0, float d1) {
return max(d0, -d1);
}
float distanceToRect( float2 point, float2 center, float2 size ) {
point -= center;
point = abs(point);
point -= size / 2.;
return max(point.x, point.y);
}
float distanceToScene( float2 point ) {
float d2r1 = distanceToRect( point, float2(0.), float2(0.45, 0.85)
);
float2 mod = point - 0.1 * floor(point / 0.1);
float d2r2 = distanceToRect( mod, float2( 0.05 ), float2(0.02, 0.04) );
float diff = differenceOp(d2r1, d2r2);
return diff;
}
上面的代码中，differenceOp（）函数用于获取两个距离(signed distances)之间的差异。当我们需要绘制出来其他形状的时候，我们需要用到这个函数。distanceToRect（）函数用于确定给定的点是在内部还是外部。point -= center用于抵消给定当前坐标的中心位置。point = abs(point)我们得到给定点的对称坐标。point -= size / 2.得到距离任何边缘的距离。distanceToScene（）用来获取与场景中任意对象之间的最近的距离。
kernel void compute(texture2d<float, access::write> output [[texture(0)]],
constant float &timer [[buffer(0)]],
uint2 gid [[thread_position_in_grid]])
{
int width = output.get_width();
int height = output.get_height();
float2 uv = float2(gid) / float2(width, height);
uv = uv * 2.0 - 1.0;
float d2scene = distanceToScene(uv);
bool i = d2scene < 0.0;
float4 color = i ? float4( .1, .5, .5, 1. ) : float4( .7, .8, .8, 1. );
output.write(color, gid);
}
效果图：
接下来，需要显示出来阴影效果。第一步：我们需要获得和光线之间的距离。其次：获得光线的方向。第三步：沿着光线的方向到达光源或者到达物体。我们需要在lightPos位置创建一个灯光，为了更好地显示，我们需要为这个灯光添加一个动画效果，然后我们得到任意一个给顶点的距离lightPos的距离，然后根据和光线之间的距离进行着色。距离物体越近，颜色越淡，距离越远，光线越亮。为了避免灯光的亮度出现负数，我们使用max()函数：
float2 lightPos = float2(1.3 * sin(timer), 1.3 * cos(timer));
float dist2light = length(lightPos - uv);
color *= max(0.0, 2. - dist2light );
output.write(color, gid);
现在这个物体像是透明的，并没有实际的阴影效果，我们继续优化：
float getShadow(float2 point, float2 lightPos) {
float2 lightDir = lightPos - point;
float dist2light = length(lightDir);
for (float i=0.; i < 300.; i++) {
float distAlongRay = dist2light * (i / 300.);
float2 currentPoint = point + lightDir * distAlongRay;
float d2scene = distanceToScene(currentPoint);
if (d2scene <= 0.) { return 0.; }
}
return 1.;
}
上面这个函数的意思是：float2 lightDir = lightPos - point;用来获取从点到光源的方向。float dist2light = length(lightDir);获取点到光源之间的距离。后面就是一个for循环把光线分成若干个比较小的步骤。如果不使用这个循环，可能就会在阴影后面留下黑色的洞。接下来，我们计算我们当前光线的距离，然后沿着光线移动这个距离，知道找到我们正在采样的空间点。然后，我们看到我们距离表面有多远，然后测试我们是否在一个物体内。如果是，因为处在阴影中，就返回0。否则就说明光线没有投射到物体上，返回1：
float shadow = getShadow(uv, lightPos);
shadow = shadow * 0.5 + 0.5;
color *= shadow;
output.write(color, gid);
就像代码中设置的，我们使用0.5来减弱阴影效果，也可以使用其他的数值。
到目前为止，大概的效果图出来了，只不过，现在的循环是以一个像素的步长进行的，这样性能不太友好，我们可以通过增加射线的"速度"来改善这一点。也就是说，我们不需要把步长设置这么小，我们可以安全地想任意一个方向移动人以距离，而不是固定的步长。这样我们就可以快速地跳过空白区域，当找到距离最近曲面的距离时，我们不知道曲面的方向，所以实际上我们有一个圆的半径与场景的最近部分相交。我们可以沿着光线追踪，总是踩到圆的边缘，直到圆半径变为0，这意味着它与一个表面相交。这就是我们上次学到的射线技术！只需使用以下行替换getShadow（）函数的内容：
float2 lightDir = normalize(lightPos - point);
float dist2light = length(lightDir);
float distAlongRay = 0.0;
for (float i=0.0; i < 80.; i++) {
float2 currentPoint = point + lightDir * distAlongRay;
float d2scene = distanceToScene(currentPoint);
if (d2scene <= 0.001) { return 0.0; }
distAlongRay += d2scene;
if (distAlongRay > dist2light) { break; }
}
return 1.;
在raymarching里面，该步骤的大小取决于从表面的距离。在空旷的地方，它会跳得很远。但如果它与物体平行并靠近物体，则距离总是很小，因此跳跃尺寸也很小。这意味着光线传播速度非常慢。通过固定的步数，它不会走得太远。通过80步或更多步骤，我们应该避免在阴影中获得“漏洞”。
