第一段代码，单张纹理

Shader "MyShader/Single Texture"
{
   Properties
   {
      _Color ("Color Tint", Color) = (1, 1, 1, 1)
      _MainTex ("Main Tex", 2D) = "white" {}
      _Specular ("Specular", Color) = (1, 1, 1, 1)
      _Gloss ("Gloss", Range(8.0, 256)) = 20
   }
   SubShader
   {
       Pass{
       
           Tags{"LightMode" = "ForwardBase"}
                      
           CGPROGRAM
           
           #pragma vertex vert
           #pragma fragment frag
           
           #include "Lighting.cginc"
           
           fixed4 _Color;
           sampler2D _MainTex;
           float4 _MainTex_ST;
           fixed4 _Specular;
           float _Gloss;    
           
           struct a2v{
            float4 vertex : POSITION;
            float3 normal : NORMAL;
            float4 texcoord : TEXCOORD0;
           };
           
           struct v2f{
            float4 pos : SV_POSITION;
            float3 worldNormal : TEXCOORD0;
            float3 worldPos : TEXCOORD1;
            float2 uv : TEXCOORD2;
           };
           
           v2f vert(a2v v){
            v2f o;
            o.pos = UnityObjectToClipPos(v.vertex);            
            o.worldNormal = UnityObjectToWorldNormal(v.normal);            
            o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;            
            o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;            
            return o;
           }
           
           fixed4 frag(v2f i): SV_Target{
            fixed3 worldNormal = normalize(i.worldNormal);
            fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));            
            // Use the texture to sample the diffuse color
            fixed3 albedo = tex2D(_MainTex, i.uv).rgb * _Color.rgb;            
            fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;            
            fixed3 diffuse = _LightColor0.rgb * albedo * max(0, dot(worldNormal, worldLightDir));            
            fixed3 viewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
            fixed3 halfDir = normalize(worldLightDir + viewDir);
            fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0, dot(worldNormal, halfDir)), _Gloss);            
            return fixed4(ambient + diffuse + specular, 1.0);
           }        
           
           ENDCG
       }
   }   
   FallBack "Specular"   
}

效果：

说明：

1. Tags{"LightMode" = "ForwardBase"} 中，LightMode 标签是 Pass 标签中的一种，它用于定义该 Pass 在 Unity 的光照流水线中的角色。
2. 变量 float4 _MainTex_ST 的名字不是随便起的。在 Unity 中，我们使用 纹理名_ST 的方式来声明某个纹理的属性。其中，ST 是缩放（scale）和平移（translation）的缩写。_MainTex_ST 可以让我们得到该纹理的缩放和平移值， _MainTex_ST.xy 存放缩放值，_MainTex_ST.zw 存放偏移值。
3. 结构体的定义中，我们在 a2v 结构体中使用 TEXCOORD0 语义声明了一个新的变量 texcoord，这样 Unity 就会将模型的第一组纹理坐标存储到该变量中。然后，我们在 v2f 结构体中添加了用于存储纹理坐标的变量 uv，以便在片元着色器中使用该坐标进行纹理采样。
4. 在顶点着色器 v2f vert(a2v v){} 中，我们使用纹理的属性值 _MainTex_ST 来对顶点纹理坐标进行变换，得到最终的纹理坐标。Unity 提供了一个内置宏 TRANSFORM_TEX 来帮助我们计算上述过程：o.uv = TRANSFORM_TEX(v.texcoord, _MainTex);
5. 好吧片元着色器看的似懂非懂。